Jon Hartmann

Nice - I wrote an almost identical udf some time ago. Pretty cool how similar both techniques are. I actually chose to have mine to return values like StructAppend() does. Works the same in the end tho.

http://www.cflib.org/udf/structBlend

cfscript version :

public struct function structMerge(
      required struct destStruct,
      required struct sourceStruct,
      boolean overwrite = true
   )
   {
      // Loop Keys
      for( local.key in arguments.sourceStruct ) {
         // Find if the new key from sourceStruct Exists in destStruct
         if( structKeyExists( arguments.destStruct, local.key) ) {
            // If they are both structs, we need to merge those structs, too
            if( isStruct( arguments.destStruct[ local.key ] ) and isStruct(arguments.sourceStruct[local.key] ) ) {
               // Recursively call StructMerge to merge those structs
               structMerge( arguments.destStruct[ local.key ], arguments.sourceStruct[ local.key ], arguments.overwrite )
            }
            // We already checked that the key existed, now we just check if we can overwrite it
            else if( arguments.overwrite ) {
               arguments.destStruct[ local.key ] = arguments.sourceStruct[ local.key ];
            }
            // The unused case here is if Overwrite is false, in which case destStruct is not changed
         }
         // If it doesn't exist, you're free to merge
         else {
            arguments.destStruct[ local.key ] = arguments.sourceStruct[ local.key ];
         }
      }

      return arguments.destStruct;
   }